/*------------------<--- Start of Description -->--------------------\
| Sample size for comparison of two median survival curves;          |
| Provides approximate sample size for logrank test.                 |
| Assumptions are uniform accrual and exponential survival           |
|--------------------<--- End of Description -->---------------------|
|--------------------------------------------------------------------|
|--------------<--- Start of Files or Arguments Needed -->-----------|
| Arguments:                                                         |
|   - Required:                                                      |
|     T0 = length of accrual period(uniform accrual assumed)         |
|     T  = total length of study(=T0+follow-up after last patient)   |
|     y1 = true group 1 median survival                              |
|     min_y2 = smallest possible true group 2 median survival        |
|   - Optional:                                                      |
|     max_y2 = largest possible true median survival for group 2     |
|     inc_y2 = increment value for range of y2                       |
|     r = ratio of group 2/group 1 sample size(n2/n1),default=1      |
|     alpha = type 1 error, e.g. .01 or .05, default=.05             |
|     sides = 1 or 2 for 1 or 2 sided test, default=2                |
|     power = desired power, e.g. .80, .90, default=.80              |
|     plot  = 'P' for line printer plot of group 2 sample size vs y2 |
|             'G' for SAS/GRAPH plot of group 2 sample size vs y2    |
|     unit  = units for time, e.g. years, months, days, hours        |
| Output:  Sample size per group for true group 1 mean of y1 vs true |
|          group 2 means ranging from min_y2 to max_y2               |
|---------------<--- End of Files or Arguments Needed -->------------|
|--------------------------------------------------------------------|
|----------------<--- Start of Example and Usage -->-----------------|
| Example: %sv2md_ss(sides=1,power=.9,y1=3.466,min_y2=0.31,          |
|                   max_y2=2.31,inc_y2=.2, t0=3,t=5,unit=yrs,plot=p);|
| Usage:   %sv2md_ss (ALPHA=.05,SIDES=2,POWER=.80,Y1=.,MIN_Y2=.,     |
|                   MAX_Y2=.,INC_Y2=.,R=1,T0=.,T=.,PLOT= , UNIT=);   |
| Reference: Bergstralh, EJ.  SAS macros for sample size and power   |
|            calculations.  Proceedings of the 9th annual SAS Users  |
|            Group International Conference.                         |
|            Equation #17.                                           |
\-------------------<--- End of Example and Usage -->---------------*/
%MACRO sv2md_ss (ALPHA=.05,SIDES=2,POWER=.80,Y1=.,MIN_Y2=.,
                MAX_Y2=.,INC_Y2=.,R=1,T0=.,T=.,PLOT= , UNIT=);
/*--------------------------------------------\
| Author:  Michael Riggs and Eric Bergstralh; |
| Purpose: Sample size for comparison of two  |
|          median survival curves;            |
\--------------------------------------------*/

 OPTIONS MISSING=' ' NOCENTER;
   %LET PLOT=%UPCASE(&PLOT);
 DATA T1;
      ALPHA=&ALPHA;
      SIDES=&SIDES;
      Y1=&Y1;
      MIN_Y2=&MIN_Y2;
      MAX_Y2=&MAX_Y2;
      INC_Y2=&INC_Y2;
      POWER=&POWER;
      R=&R;
      T0=&T0;
      T=&T;
    ZALPHA=(PROBIT(1-ALPHA))*(SIDES=1) + (PROBIT(1-ALPHA/2))*(SIDES=2);
    ZBETA=PROBIT(POWER);
    IF MAX_Y2=. THEN DO;
      MAX_Y2=MIN_Y2+1; INC_Y2=MIN_Y2+2;  *NEED 1 EXEC OF DO;
    END;
    TY1=Y1;
    TT=T;
    TT0=T0;
    TR=R;
    CALL SYMPUT ('TOTFOL', PUT((T-T0),4.1));
    DO Y2=MIN_Y2 TO MAX_Y2 BY INC_Y2;
       LAMBDA1=LOG(2)/TY1;
       LAMBDA2=LOG(2)/Y2;
       LAMBD_BR=(LAMBDA1+TR*LAMBDA2)/(1+TR);
       IF TT0 GT 0 THEN DO;
         PHILBDA1=LAMBDA1**2   *
                  1/ (1-(EXP(-LAMBDA1*(TT-TT0))-EXP(-LAMBDA1*TT)) /
                               (LAMBDA1*TT0) );
         PHILBDA2=LAMBDA2**2   *
                  1/ (1-(EXP(-LAMBDA2*(TT-TT0))-EXP(-LAMBDA2*TT)) /
                               (LAMBDA2*TT0) );
         PHILBDBR=LAMBD_BR**2  *
                  1/ (1-(EXP(-LAMBD_BR*(TT-TT0))-EXP(-LAMBD_BR*TT)) /
                               (LAMBD_BR*TT0) );
       END;
       IF TT0=0 THEN DO;  *ALL PTS ENTER STUDY AT SAME TIME;
          PHILBDA1=LAMBDA1**2/(1-EXP(-LAMBDA1*TT));
          PHILBDA2=LAMBDA2**2/(1-EXP(-LAMBDA2*TT));
          PHILBDBR=LAMBD_BR**2/(1-EXP(-LAMBD_BR*TT));
       END;
       N1=((ZALPHA*SQRT(PHILBDBR*(1+1/TR)) +
          ZBETA*SQRT(PHILBDA1+PHILBDA2/TR))   /
         (LAMBDA1-LAMBDA2) ) **2;
       N1=CEIL(N1);
       N2=N1*TR;
       OUTPUT;
     END;
 LABEL Y1="Group 1*Median (&UNIT)*Survival"
       Y2="Group 2*Median (&UNIT)*Survival"
       T0="Recruitment*Period*(&unit)"
       n1="Group 1*Sample Size"
       n2="Group 2*Sample Size"
       T="Time*(&UNIT) of*Analysis";
 PROC PRINT SPLIT='*';
      ID Y1; var Y2 N1 N2;
 TITLE3
    "SAMPLE SIZE REQUIREMENTS FOR COMPARISON OF TWO MEDIAN SURVIVALS";

TITLE4"Uniform accrual for &t0 &unit(T0) is assumed with analysis at &t &unit
(T)";
 title5
 "Alpha=&alpha, Sides=&sides, Power=&power, Ratio N2/N1=&r, True Group 1
 Median Survival=&y1 &unit";

%IF &MAX_Y2 NE . %THEN %DO;
    %IF &PLOT= P  %THEN %DO;
      PROC PLOT NOLEGEND;
           PLOT N2*Y2/ HAXIS=&MIN_Y2 TO &MAX_Y2 BY &INC_Y2;
            LABEL N2='Group 2 sample size'
                  Y2="Group2 median survival(&unit)";
    %END;
    %ELSE %IF &PLOT= G  %THEN %DO;
          PROC GPLOT ;
           PLOT N2*Y2;
           SYMBOL1  F=SPECIAL V=J H=1 I=j       L=1;
           SYMBOL2  F=SPECIAL V=M H=1   I=j       L=2;
              LABEL N2='N2'
                    Y2="Group 2 median survival(&unit)";
                run; quit;
    %END;
    RUN;
%END;
%MEND sv2md_ss;